Software Vault: The Gold Collection/Software Vault - The Gold Collection (American Databankers) (1993).ISO/cdr10/qhlpc.zip/QHLPC.ZIP/QHSETUP.BAT

DOS Batch File | 1993-03-01 | 13KB | 355 lines

echo off
cls

SET V1=0
SET V2=0
SET V3=0
if not "%V1%"=="0" goto ENV
if not "%V2%"=="0" goto ENV
if not "%V3%"=="0" goto ENV

echo ╓─────────────── QHelpC (C), SHAREWARE RELEASE Version 2.15a ───────────────╖
echo ║                 ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀                 ║
echo ║  This QHelpC setup program will:                                            ║
echo ║  MAKE a sub-DIR C:\QHelpC. COPY the QHelpC.EXE, QHelpC1.EXE, QHelpC.H!      ║
echo ║  and support files to C:\QHelpC. You can customize this installation later. ║
echo ║                                                                             ║
echo ║      To run this setup utility, you MUST be logged onto the drive and       ║
echo ║      (in the sub-directory), containing ALL of the supplied QHelpC files.   ║
echo ║                                                                             ║
echo ║   The SHAREWARE QHlpC.EXE file MUST first be COPIED to a 'temporary' sub-   ║
echo ║   directory on your HARD DRIVE. The QHlpC file MUST then be EXECUTED, to    ║
echo ║   EXTRACT all of its files. NOTE THAT THE SETUP UTILITY CAN BE RUN FROM     ║
echo ║   A FLOPPY IF ALL OF THE EXTRACTED FILES WILL FIT (e.g. 5 1/4" Hi-Density   ║
echo ║   or a 3 1/2" 720K byte or 1.4M byte).                                      ║
echo ║                                                                             ║
echo ║ NOTE: If a C:\QHelpC sub-directory exists, any files located there will be  ║
echo ║       COPIED to a C:\QHelpC\QHelpC.OLD sub-directory. Note that the files   ║
echo ║       in an existing C:\QHelpC sub-directory are ONLY copied if files do    ║
echo ║       NOT already exist in a C:\QHelpC\QHelpC.OLD sub-directory. This is to ║
echo ║       prevent OVERWRITTING existing C:\QHelpC\QHelpC.OLD files.             ║
echo ║                                                         see also README.BAT ║
echo ║   Press [ CTRL C ] ... [ Y ] to abort setup, any other key to continue...   ║
echo ║                                                                             ║
echo ╚═[ SC030193d ]══════════[ QhSetup.BAT, 01 Mar 93, Rhg ]══════════[ SC0C79h ]═╝
pause > nul
cls

:                         TEST FOR ALL SOURCE FILES
if not exist yes          SET V3=1
if not exist Qh.BAT       SET V3=1
if not exist QhM.BAT      SET V3=1
if not exist QhS.BAT      SET V3=1
if not exist Readme.BAT   SET V3=1
if not exist QHelpC.DAT   SET V3=1
if not exist Register.DOC SET V3=1
if not exist QHelpC.EXE   SET V3=1
if not exist QHelpC1.EXE  SET V3=1
if not exist QHelpC.H!    SET V3=1
if not exist QhSetup.P0   SET V3=1
if not exist ReadMe.P0    SET V3=1
if not exist ReadMe.P1    SET V3=1
if not exist ReadMe.P2    SET V3=1
if not exist ReadMe.P3    SET V3=1
if not exist ReadMe.P4    SET V3=1
if not exist ReadMe.P5    SET V3=1
if not exist QHelpC.TXT   SET V3=1
if                           %V3%==1 goto ERROR

if exist C:\QHelpC\*.*               goto SaveOld?
if exist C:\QHelpC\nul               goto SetV2

SET V1=1
MD C:\QHelpC
if not exist C:\QHelpC\nul           goto ABORT

:SetV2
SET V2=5

:CopyYes
copy yes C:\ > nul
if not exist C:\yes                  goto ABORT

echo                                  QHSETUP.BAT
echo.
goto CopyNEW

:SaveOld?
if exist C:\QHelpC\QhelpC.OLD\*.* goto WARNING

if     exist C:\QHelpC\QhelpC.OLD\nul SET V2=1
if not exist C:\QHelpC\QhelpC.OLD\nul SET V2=2
if not exist C:\QHelpC\QhelpC.OLD\nul MD C:\QHelpC\QHelpC.OLD
if not exist C:\QHelpC\QhelpC.OLD\nul goto ABORT

echo                                  QHSETUP.BAT
if %V2%==1 echo SAVING   OLD C:\QHelpC files to EXISTING C:\QHelpC\QHelpC.OLD sub-DIR.
if %V2%==2 echo SAVUNG   OLD C:\QHelpC files to NEWLY CREATED C:\QHelpC\QHelpC.OLD sub-DIR.
copy QHelpC.H!     C:\QHelpC\QHelpC.OLD\DskFull1.TST > nul
if not exist       C:\QHelpC\QHelpC.OLD\DskFull1.TST goto DiskFull

copy QHelpC.H!     C:\QHelpC\QHelpC.OLD\DskFull2.TST > nul
if not exist       C:\QHelpC\QHelpC.OLD\DskFull2.TST goto DiskFull

del                C:\QHelpC\QHelpC.OLD\DskFull1.TST
del                C:\QHelpC\QHelpC.OLD\DskFull2.TST
copy C:\QHelpC\*.* C:\QHelpC\QHelpC.OLD > nul
copy yes           C:\ > nul

:CopyNEW
if exist C:\QHelpC\*.* echo DELETING OLD C:\QHelpC files...
if exist C:\QHelpC\*.* del C:\QHelpC\*.* < C:\yes > nul
if %V1%==1 echo COPYING  17 files, to NEWLY CREATED C:\QHelpC ... please stand by...
if %V1%==0 echo COPYING  17 files, to EXISTING C:\QHelpC ... please stand by...
           echo          NOTE: If the installation is being made from a FLOPPY DRIVE, do NOT
           echo                remove the diskette from the floppy drive until told to do so!
copy Qh.BAT       C:\QHelpC
copy Qhm.BAT      C:\QHelpC
copy Qhs.BAT      C:\QHelpC
copy Readme.BAT   C:\QHelpC
copy QHelpC.DAT   C:\QHelpC
copy Register.DOC C:\QHelpC
copy QHelpC.EXE   C:\QHelpC
copy QHelpC1.EXE  C:\QHelpC
copy QHelpC.H!    C:\QHelpC
copy Readme.P0    C:\QHelpC
copy Readme.P1    C:\QHelpC
copy Readme.P2    C:\QHelpC
copy Readme.P3    C:\QHelpC
copy Readme.P4    C:\QHelpC
copy Readme.P5    C:\QHelpC
copy QHelpC.TXT   C:\QHelpC
copy QhSetup.P0   C:\QHelpC

:                              CHECK INSTALLATION
C:
CD \QHelpC
if not exist Qh.BAT       SET V3=2
if not exist QhM.BAT      SET V3=2
if not exist QhS.BAT      SET V3=2
if not exist Readme.BAT   SET V3=2
if not exist QHelpC.DAT   SET V3=2
if not exist Register.DOC SET V3=2
if not exist QHelpC.EXE   SET V3=2
if not exist QHelpC1.EXE  SET V3=2
if not exist QHelpC.H!    SET V3=2
if not exist QhSetup.P0   SET V3=2
if not exist ReadMe.P0    SET V3=2
if not exist ReadMe.P1    SET V3=2
if not exist ReadMe.P2    SET V3=2
if not exist ReadMe.P3    SET V3=2
if not exist ReadMe.P4    SET V3=2
if not exist ReadMe.P5    SET V3=2
if not exist QHelpC.TXT   SET V3=2
if                           %V3%==2 goto ERROR

echo                           Press any key to continue...
pause > nul

:               INSTALLATION SUCCESSFUL... Invoke QHelpC @ LOGO
QHelpC QhelpC

cls
echo                                  QHSETUP.BAT
echo.
if %V2%==0 echo           C:\QHelpC\QHelpC.OLD DIR and files existed, therefore
if %V2%==0 echo           (with your permission), OLD C:\QHelpC files were NOT saved.
if %V2%==0 goto byPass
if %V2%==5 goto byPass1

echo.
echo NOTE: Files from an existing C:\QHelpC sub-directory were COPIED to the
echo       C:\QHelpC\QHelpC.OLD sub-directory. If you wish to SAVE these files,
echo       you should COPY them to a FLOPPY and then DELETE the files from the
echo       C:\QHelpC\QHelpC.OLD sub-directory. Then REMOVE the sub-directory.

:byPass
echo.
echo       Note that the files in an existing C:\QHelpC sub-directory are ONLY
echo       saved if files do NOT already exist in a C:\QHelpC\QHelpC.OLD
echo       sub-directory. This is done to prevent OVERWRITTING any existing
echo       C:\QHelpC\QHelpC.OLD files.

:byPass1
echo.
echo.
echo       IF you created a 'temporary' sub-directory, on your HARD DRIVE,
echo       for the self-extractor ( QHlpC.EXE ), and the extracted files;
echo.
echo           DELETE all of the files in  the 'temporary' sub-directory
echo           you created.  Then, REMOVE  the 'temporary' sub-directory.
echo 
echo                          Press any key to continue...
pause > nul

cls
type QhSetup.P0
del  QhSetup.P0
echo                           Press any key to continue...
pause > nul
cls
echo                                  QHSETUP.BAT
echo.
goto preEND

:ENV
cls
echo                                  QHSETUP.BAT
echo.
echo              ERROR !  You do NOT have enough environmental space
echo                       to store the following needed variable(s).
echo.
if not "%V1%"=="0" echo                              'V1' requires 6 bytes
if not "%V2%"=="0" echo                              'V2' requires 6 bytes
if not "%V3%"=="0" echo                              'V3' requires 6 bytes
echo.
echo   You have two choices:
echo   The 1st., and EASIEST, is to temporarly shorten your 'PATH' by the total
echo   number of bytes shown above.  After QHelpC has been installed, you can
echo   revert back to your normal 'PATH'.
echo.
echo   The 2nd., and MOST DESIREABLE for future use, is to add a SHELL statement
echo   to your Config.SYS file.  Since the syntax ( # of bytes ), for the SHELL
echo   statement is DOS-VER dependent, it is NOT given here. See your DOS manual.
echo 
if "%V1%"=="0" SET V1=
if "%V2%"=="0" SET V2=
if "%V3%"=="0" SET V3=
goto END

:ERROR
cls
echo                                  QHSETUP.BAT
echo.
if %V3%==2 echo ERROR ! The following file(s) did NOT get COPIED to the C:\QHelpC
if %V3%==2 echo ▀▀▀▀▀   sub-directory. INSTALLATION FAILED! PROBABLE CAUSE = DISK FULL.
if %V3%==2              goto SkipYes

if %V3%==1 echo ERROR ! Can NOT find the following SOURCE file(s). You MUST execute QhSetup
if %V3%==1 echo ▀▀▀▀▀   from the DRIVE and DIR containing ALL of the QHelpC SOURCE files.
if not exist yes          echo yes

:SkipYes
if not exist Qh.BAT       echo Qh.BAT
if not exist Qhm.BAT      echo Qhm.BAT
if not exist Qhs.BAT      echo Qhs.BAT
if not exist Readme.BAT   echo ReadMe.BAT
if not exist QHelpC.DAT   echo QHelpC.DAT
if not exist Register.DOC echo Register.DOC
if not exist QHelpC.EXE   echo QHelpC.EXE
if not exist QHelpC1.EXE  echo QHelpC1.EXE
if not exist QHelpC.H!    echo QHelpC.H!
if not exist QhSetup.P0   echo QhSetup.P0
if not exist ReadMe.P0    echo ReadMe.P0
if not exist ReadMe.P1    echo ReadMe.P1
if not exist ReadMe.P2    echo ReadMe.P2
if not exist ReadMe.P3    echo ReadMe.P3
if not exist ReadMe.P4    echo ReadMe.P4
if not exist ReadMe.P5    echo ReadMe.P5
if not exist QHelpC.TXT   echo QHelpC.TXT
           echo                          ABORTING QHelpC INSTALLATION
if %V3%==1 goto SrcERR

if %V2%==0 echo                  At your request, your old C:\QHelpC files were
if %V2%==0 echo                  NOT SAVED, and therefore CAN NOT be restored.

:SrcERR
echo                          Press any key to continue...
pause > nul

cls
echo                                  QHSETUP.BAT
echo.
if %V3%==1 goto preEND

if not %V2%==0 echo                System RESTORED to pre-INSTALLATION conditions.
                    CD \
if exist QHelpC\*.* del QHelpC\*.* < yes > nul

if %V2%==0 goto RD_DIR
if %V2%==5 goto RD_DIR

           CD   QHelpC
           copy QHelpC.OLD\*.* > nul
           del  QHelpC.OLD\*.* < C:\yes > nul
if %V2%==2 RD   QHelpC.OLD

:RD_DIR
           CD \
if %V1%==1 RD QHelpC
           goto preEND

:ABORT
cls
echo                                  QHSETUP.BAT
echo.
echo                     DISK FULL ERROR... unable to Continue...
echo                     NOT enough space for even a single file.
goto Abort1

:WARNING
echo                                  QHSETUP.BAT
echo.
echo WARNING:       Existing C:\QHelpC files CAN NOT be SAVED because
echo ▀▀▀▀▀▀▀        a C:\QHelpC\QHelpC.OLD DIR and files already exist.
echo.
echo      If you elect to continue, your old C:\QHelpC files will be DELETED.
echo.
echo          ┌──────────────────────────────────────────────────────────┐
echo          │    If you WANT to SAVE your existing C:\QHelpC files;    │
echo          │ PRESS [ CTRL C ] [ Y ] ... to ABORT QHelpC INSTALLATION. │
echo          └──────────────────────────────────────────────────────────┘
echo.
echo    THEN  SAVE the files in the C:\QHelpC sub-DIR to a FLOPPY and then
echo          DELETE the C:\QHelpC files.
echo.
echo     OR   SAVE the files in the C:\QHelpC\QHelpC.OLD sub-DIR to a FLOPPY,
echo          and then DELETE the files in  the C:\QHelpC\QHelpC.OLD sub-DIR.
echo          It is NOT necessary to remove the C:\QHelpC\QHelpC.OLD sub-DIR.
echo.
echo               ┌──────────────────────────────────────────────────┐
echo               │ If you do NOT want to SAVE your C:\QHelpC files, │
echo               │ PRESS any key to CONTINUE QHelpC INSTALLATION... │
echo               └──────────────────────────────────────────────────┘
echo 
pause > nul
cls
goto CopyYes

:DiskFull
cls
echo                                  QHSETUP.BAT
echo.
echo DISK FULL ERROR !
echo ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀  There is probably NOT enough HARD DISK space to SAVE the
echo                  existing C:\QHelpC files to C:\QHelpC\QHelpC.OLD sub-DIR.
echo.
echo                  Suggest you       COPY   your existing C:\QHelpC files
echo                  to a FLOPPY. Then DELETE your existing C:\QHelpC files
echo                  and re-RUN this QhSetup utility.
echo.
echo                  RESTORING system to pre-INSTALLATION conditions.
if exist C:\QHelpC\QHelpC.OLD\*.* del C:\QHelpC\QHelpC.OLD\*.* < yes > nul
if %V2%==2                        RD  C:\QHelpC\QHelpC.OLD

:Abort1
echo.
echo                           ABORTING QHelpC INSTALLATION
echo.
if exist C:\QHelpC\*.* CD C:\QHelpC

:preEND
echo.
if exist C:\yes del C:\yes
SET V1=
SET V2=
SET V3=
echo.
echo            If the QHelpC INSTALLATION was run from a FLOPPY DRIVE;
echo                AFTER the floppy drive LIGHT has gone OUT, you
echo                CAN remove the diskette from the floppy drive.
echo 
goto END

:END